PowerPoint Shadows

Scenario:

You have a presentation made in a pre 2007 version that has animated shadowed text. When you run it in your new 2007 version the text seems to appear twice!

PowerPoint MVP Echo Swinford explains whats going on here: http://www.echosvoice.com/2007/shadows.htm

Suppose though you have dozens of affected presentations to fix! This code will automate the process. Create a folder called 'Files' on your desktop and COPY the ppt / pps files into it. Run the code below and you should have fixed presentations in the same 'Files' folder.

Sub ShadowFix()

Dim osld As Slide
Dim oshp As Shape
Dim strFolder As String
Dim strSpec As String
Dim strName As String
Dim oPres As Presentation

strFolder = Environ("USERPROFILE") & "\Desktop\Files\"
strSpec = "*.PP*"
strName = Dir$(strFolder & strSpec)

While strName <> ""
Set oPres = Presentations.Open(strFolder & strName, msoFalse)
For Each osld In oPres.Slides
For Each oshp In osld.Shapes
If oshp.Fill.Visible = False Then
If oshp.HasTextFrame Then
If oshp.TextFrame.HasText Then
If oshp.Shadow.Visible = True Then
oshp.Shadow.Visible = False
oshp.TextFrame.TextRange.Font.Shadow = True
End If
End If
End If
End If
Next
Next
oPres.SaveCopyAs oPres.Path & "\fix_" & oPres.Name
oPres.Close
Set oPres = Nothing
strName = Dir()
Wend
End Sub

Don't know how to use code? See here for instructions

Back to the Index Page

POWERPOINT BLOG

Articles on your favourite sport

Free Microsoft PowerPoint Advice, help and tutorials, Template Links
This website is sponsored by Technology Trish Ltd
© Technology Trish 2007
Registered in England and Wales No.5780175
PowerPoint® is a registered trademark of the Microsoft Corporation